Programmi Visual Basic - prof.Claudio Maccherani

Programmi Visual Basic - prof. Claudio Maccherani - Perugia - 2009
accesso a database (Access) in Visual Basic 6.0 con Jet, DAO e DataControl
Jet (Microsoft Jet Database Engine) - DAO (Data Access Objects)

applicazione Alunni1 - database MS Access Alunni.mdb - tabella Alunni
Tabella ALUNNI:
Matricola long, Nome string_*30, Data Nascita date, Luogo Nascita string_*20,
Classe integer, Sezione string_*1, Corso string_*1
datAlunni	Connect	Access	txtMatricola	DataSource	datAlunni
[Data]	dataBaseName	Alunni.mdb		DataField	Matricola
	Recordset Type	0 - Table	txtNome	DataSource	datAlunni
	RecordSource	Alunni		DataField	Nome
			txtData	DataSource	datAlunni
				DataField	Data Nascita

 '+------------------------------------------------------------------------------------+
 '| ALUNNI1 - applicazione esempio di gestione singola tabella                         |
 '|           utilizzando JET (Microsoft Jet Database Engine) - Data Control           |
 '|           [Prof. Claudio Maccherani]                                               |
 '+------------------------------------------------------------------------------------+
 Option Explicit ' per controllare la dichiarazione delle variabili
 Dim Segnalibro As Variant ' segnalibro per marcare il record corrente
 Dim Matricola As Long     ' per la ricerca
 Dim Nome As String        ' per la ricerca
 Dim Classe As Integer     ' per la ricerca
 Dim FlagRic As Boolean    ' flag per il controllo errore di Validate in caso di ricerca
 Dim boAnnulla As Boolean  ' per annullare "Nuovo" alunno
 '--------------------------------------------------------------------------------------
 Private Sub Form_Load()   ' viene eseguito al momento del caricamento in memoria del form
   ' al caricamento si possono impostare le proprietà dei controlli
   ' la proprietà Path dell'oggetto App restituisce  il percorso dell'applicazione
   ' inizializzazione proprietà del controllo Data
   datAlunni.Connect = "Access"      ' origine del database
   datAlunni.DatabaseName = App.Path & "\Alunni.mdb" ' percorso e nome database
   datAlunni.RecordsetType = 0       ' tipo di recordset (0-table)
   datAlunni.RecordSource = "Alunni" ' tabella
   boAnnulla = False
   ' Imposta le dimensioni del form
   Me.Left = (Screen.Width - Me.Width) / 2: Me.Top = (Screen.Height - Me.Height) / 2
   ' Centra il form
   Me.Move (Screen.Width - Width) / 2, (Screen.Height - Height) / 2
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub Form_Activate() ' viene eseguito quando il form diventa attivo, subito dopo il caricamento
   selIndexMatricola = True ' imposta il pulsante dell'indice matricola (indice primario)
   FlagRic = False          ' imposta il flag della ricerca
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdFirst_Click() ' pulsante FIRST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveFirst ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdNext_Click() ' pulsante NEXT
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveNext    ' va al prossimo record (dell'indice corrente)
      If datAlunni.Recordset.EOF Then ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveLast ' e se si torna sull'ultimo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdPrevious_Click() ' pulsante PREV
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MovePrevious ' va al precedente record (dell'indice corrente)
      If datAlunni.Recordset.BOF Then  ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveFirst ' e se si torna sul primo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdLast_Click() ' pulsante LAST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveLast ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdNuovo_Click()  ' pulsante NUOVO
   datAlunni.Recordset.AddNew ' aggiunge un record vuoto
   MsgBox "Inserisci i dati e memorizza lo studente con il pulsante SALVA"
   txtMatricola.SetFocus      ' posiziona il cursore sulla matricola
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdAnnulla_Click() ' pulsante annulla
   boAnnulla = True            ' annulla l'ADDNEW del pulsante NUOVO
   datAlunni.Recordset.MoveLast
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdSalva_Click()  ' pulsante SALVA
   If datAlunni.Recordset.BOF And datAlunni.Recordset.EOF Then
      Exit Sub ' se tabella vuota (prima non si è fatto neppure l'AddNew), esce
   End If
   On Error GoTo Errore_Salva ' attiva la gestione dell'errore
   Segnalibro = datAlunni.Recordset.Bookmark ' imposta segnalibro sul record corrente
   datAlunni.Recordset.Update ' memorizza le variazioni del record corrente
   datAlunni.Recordset.Bookmark = Segnalibro ' si riposiziona sul record appebna variato
   MsgBox "Studente registrato / variato"
   On Error GoTo 0 ' disabilita la gestione dell'errore
   Exit Sub
 Errore_Salva: ' gestione dell'errore
   ' l'errore numero 3020 si verifica se si usa "Salva" (Update) senza prima "Nuovo" (AddNew)
   If Err.Number <> 3020 Then ' Update senza AddNew o Update
      ' in err.number c'è il codice dell'errore e in err.description la sua descrizione
      MsgBox "Errore " & Err.Number & " " & Err.Description
   End If
   ' riprende l'esecuzione dall'istruzione seguente quella che ha provocato l'errore
   Resume Next
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdCanc_Click() ' pulsante CANC
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      If MsgBox("Confermi la cancellazione dello studente corrente ?", vbYesNo) = vbYes Then
         ' dopo aver controllato che la tabella non sia vuota ..
         datAlunni.Recordset.Delete ' cancella il record corrente
         cmdNext_Click              ' si posiziona sul record successivo
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdFine_Click() ' pulsante FINE
   End ' chiusura programma
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub datAlunni_Validate(Action As Integer, Save As Integer)
   ' l'evento Validate si verifica subito prima che un record
   ' diventi corrente (Move) o con AddNew, Delete, Update
   ' qui si possono fare dei controlli e, se non va bene,
   ' si può annullare l'operazione
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      If boAnnulla Then ' annulla "nuovo" alunno
         Save = 0: boAnnulla = False: Exit Sub
      End If
      If Not FlagRic Then
      ' se il validate NON è stato attivato dalla SEEK della ricerca esegue i controlli
         If Len(txtMatricola) = 0 Then ' controllo esistenza matricola
            MsgBox "Manca la Matricola !" ' segnala l'errore
            Action = 0   ' annulla l'azione che ha causato il Validate
            Save = False ' annulla la memorizzazione di eventuali variazioni
            txtMatricola.SetFocus ' posiziona il cursore sulla matricola
         End If
         If Val(txtClasse) < 1 Or Val(txtClasse) > 5 Then ' controllo correttezza classe
            MsgBox "Classe errata !" ' segnala l'errore
            Action = 0   ' annulla l'azione che ha causato il Validate
            Save = False ' annulla la memorizzazione di eventuali variazioni
            txtClasse.SetFocus ' posiziona il cursore sulla matricola
         End If
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexMatricola_Click() ' pulsante di opzione MATRICOLA
   datAlunni.Recordset.Index = "Matricola" ' attiva l'indice Matricola
   cmdFirst_Click ' si posiziona sul primo record (dell'indice attivato)
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexNome_Click() ' pulsante di opzione NOME
   datAlunni.Recordset.Index = "Nome" ' attiva l'indice Nome
   cmdFirst_Click ' si posiziona sul primo record (dell'indice attivato)
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexClasse_Click()  ' pulsante di opzione CLASSE
   datAlunni.Recordset.Index = "Classe" ' attiva l'indice CLASSE
   cmdFirst_Click ' si posiziona sul primo record (dell'indice attivato)
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdRicerca_Click() ' pulsante RICERCA
   If datAlunni.Recordset.BOF And datAlunni.Recordset.EOF Then
      Exit Sub ' se la tabella è vuota, esce
   End If
   FlagRic = True ' imposta il flag per i controlli del validate
   Segnalibro = datAlunni.Recordset.Bookmark ' imposta il segnalibro su record corrente
   ' imposta la ricerca in base all'indice corrente
   If selIndexMatricola Then ' se l'indice corrente è Matricola
      ' richiede la matricola da cercare
      Matricola = InputBox("Matricola da cercare (>=)")
      ' si posiziona sulla prima matricola > o = a quella data
      datAlunni.Recordset.Seek ">=", Matricola
   ElseIf selIndexNome Then ' se l'indice corrente è Nome
      ' richiede il nome da cercare
      Nome = InputBox("Nome da cercare (>=)")
      ' si posiziona sul primo nome > o = a quello dato
      datAlunni.Recordset.Seek ">=", Nome
   ElseIf selIndexClasse Then ' se l'indice corrente è Classe
      ' richiede la classe da cercare
      Classe = InputBox("Classe da cercare (>=)")
      ' si posiziona sulla prima classe > o = a quella data
      datAlunni.Recordset.Seek ">=", Classe
   End If
   ' dopo aver fatto la ricerca, sopra, con il metodo SEEK
   ' si controlla se essa ha avuto esito positivo o negativo
   If datAlunni.Recordset.NoMatch Then ' esito negativo, già segnalato da VB
      datAlunni.Recordset.Bookmark = Segnalibro ' si riposiziona sul precedente record
   End If
   FlagRic = False ' reimposta il flag per i controlli del validate
 End Sub
 '--------------------------------------------------------------------------------------